Begin AA_Book_ Test

short ActivateFlag
short EquipFlag
short SkipFlag
short state
short OnPCDrop
short OnPCEquip
short PCSkipEquip

If ( menuMode == 1 ); This makes the Script Return until Close
    if ( EquipFlag == 1 )
;     THIS IS ONLY to Write the MESSAGE as by the time you have 'equipped the book
;     i.e. READ the menu is open    
        MessageBox "You Opened up the Book [OnPCEquip]"; as menu is open now when reading
        set EquipFlag to 2
    endif
    Return
endif

if ( State == 0 )
    Set pcSkipEquip to 1
    If ( ActivateFlag == 0 ); Never Activated
        if ( OnActivate == 1 )
            MessageBox "You Picked up the Book[OnActivate] "; Menu is not open yet
;
;      HERE YOU CAN SUBSTUTE THINGS YOU WANT DONE  WHEN THE BOOK IS READ FOR THE 1ST TIME
;      TELEPORTING - CURSING - ETC
;
            Set ActivateFlag to 1
            set State to 2
            Activate; READ
            Return; Catch MenuMode
        endif
    endif
    if ( OnPCEquip == 1 ); This is for 2nd time around when 'equipped' from inventory
        Set EquipFlag to 1
        set State to 2
;
;     HERE YOU CAN PUT STUFF WHEN THE BOOK IS READ FROM INVENTORY - IT'S EQUIPPED NOW NOT ACTIVATED
;
        Activate; READ
        Return; Catch MenuMode
    endif
endif

If ( State == 2 ); reset for next time around get here when menu closes (close book)
    if ( ActivateFlag == 1 )
;
;     HERE YOU CAN PUT STUFF YOU WANT WHEN BOOK IS CLOSED FOR THE 1ST TIME
;     TELEPORT - CURSE ETC
;
        Set ActivateFlag to 2
        MessageBox "You closed the Book [OnActivate]"
        Set OnPCEquip to 0
        Set PCSkipEquip to 0
    elseif ( EquipFlag == 2 )
;
;      HERE YOU CAN PUT STUFF IF THE BOOK IS CLOSED AFTER READING FROM INVENTORY
;
        Set EquipFlag to 0
        MessageBox "You closed the Book [OnPCEquip]"
        Set OnPCEquip to 0
        Set PCSkipEquip to 0
    endif
    set State to 0; Reset
endif


if ( OnPCDrop == 1 )
;
; HERE YOU CAN PUT STUFF TO HAPPEN IF THE BOOK IS DROPPED
;
    MessageBox "You Dropped the Book [OnPCDrop]"
    set OnPCDrop to 0; have to reset Manually
    Set ActivateFlag to 0
endif

End